You are using the fake sink at the end of your pipeline. This sink just makes demand on its input (the converter) and drops the buffers. You need to use a sink which actually makes some output -- consider the file sink.

Got the same result with this:
```
 def handle_init(_ctx, socket: socket) do
    structure = [
      child(:source, %Membrane.RTMP.SourceBin{
        socket: socket,
        validator: Membrane.RTMP.DefaultMessageValidator
      })
      |> via_out(:audio)
      |> child(:decoder, Membrane.AAC.FDK.Decoder)
      |> child(:converter, %Converter{
        output_stream_format: %RawAudio{
          sample_format: :f32le,
          sample_rate: 16000,
          channels: 1
        }
      })
      |> child(:sink, %Membrane.File.Sink{location: "test.pcm"})
    ]

    {[spec: structure, playback: :playing], %{}}}
  end
```

It seems as if the buffer weren't flowing through the pipeline at all. Are there any logs that indicate, that the Source Bin is processing the packets?

I think I found my issue, I got it working by not using the Membrane.RTMP.SourceBin, but instead use Membrane.RTMP.Source, doing it that way:
```
def handle_init(_ctx, socket: socket) do
    structure = [
      child(:source, %Membrane.RTMP.Source{
        socket: socket,
        validator: Membrane.RTMP.DefaultMessageValidator
      })
      |> child(:demuxer, Membrane.FLV.Demuxer)
      |> via_out(Pad.ref(:audio, 0))
      |> child(:audio_parser, %Membrane.AAC.Parser{in_encapsulation: :none})
      |> child(:decoder, Membrane.AAC.FDK.Decoder)
      |> child(:converter, %Converter{
        output_stream_format: %RawAudio{
          sample_format: :f32le,
          sample_rate: 16000,
          channels: 1
        }
      })
      |> child(:fake_sink, Membrane.Fake.Sink.Buffers)
    ]

    {[spec: structure, playback: :playing], %{}}}
  end
```

Somehow the extra part: `|> bin_output(:audio),` that is part of the SourceBin was causing issues. Not sure exactly why, still a noob with Membrane 😄

It's because of an implicit naming of the pads. Typically, pads will take in input on a pad named `:input` and output on pads named `:output`. When this is the case, you don't need to specify a `via_{in,out}` between elements when building the pipeline.

We can see this is the case for the RTMP source and the FLV demuxer:

https://github.com/membraneframework/membrane_rtmp_plugin/blob/v0.11.2/lib/membrane_rtmp_plugin/rtmp/source/source.ex#L20

https://github.com/membraneframework/membrane_flv_plugin/blob/master/lib/membrane_flv_plugin/demuxer.ex#L40

However, notice that the FLV demuxer defines two output pads: `:audio` and `:video`. This is to be expected since demuxing is the process of splitting the stream apart into its audio and video components.

This is why you must have the `via_out` between the demuxer and the AAC parser -- you need to specify the parser will get input from the `:audio` pad of the previous element.

Apparently there is a small bug in Membrane Core. In your case with `SourceBin` you haven't linked the static output `video` pad of the `SourceBin`,  and the Core should raise an informative exception that all static pads must be linked - which does not happen.  Instead, the buffers flow doesn't start. The following children specification should work, though:
``` def handle_init(_ctx, socket: socket) do
    structure = [
      child(:source, %Membrane.RTMP.SourceBin{
        socket: socket,
        validator: Membrane.RTMP.DefaultMessageValidator
      })
      |> via_out(:audio)
      |> child(:decoder, Membrane.AAC.FDK.Decoder)
      |> child(:converter, %Converter{
        output_stream_format: %RawAudio{
          sample_format: :f32le,
          sample_rate: 16000,
          channels: 1
        }
      })
      |> child(:fake_sink, Membrane.Fake.Sink.Buffers),
      get_child(:source) |> via_out(:video) |>     child(:fake_sink2, Membrane.Fake.Sink.Buffers)
    ]

    {[spec: structure, playback: :playing], %{}}}
  end
```

Ah I see interesting, now it makes more sense thanks !

You are welcome!  In case you are still experimenting with that, just please let us know if my proposed solution works, so we will be able to mark the thread as "closed" 😉

Pipeline with RTMP source and AAC decoder

enzoqtvf

9 responses

Join out Discord Community